Function Reference

_GUICtrlEditLineFromChar

Retrieves the index of the line that contains the specified character index in a multiline edit control.

#Include <GuiEdit.au3>
_GUICtrlEditLineFromChar($h_edit[, $i_index = -1])

Parameters

$h_edit	control id/control hWnd
$i_index	Optional: Specifies the character index of the character contained in the line whose number is to be retrieved.

Return Value

The return value is the zero-based line number of the line containing the character index specified by $i_index.

Remarks

If $i_index is û1, _GUICtrlEditLineFromChar retrieves either the line number of the current line
(the line containing the caret) or, if there is a selection, the line number of the line containing
the beginning of the selection.

Related

_GUICtrlEditLineIndex

Example

#include <GUIConstants.au3>
#include <GuiEdit.au3>

opt('MustDeclareVars', 1)

Dim $myedit, $Status, $msg, $Btn_GET

GUICreate("Edit Line From Char", 392, 254)

$myedit = GUICtrlCreateEdit("First line" & @CRLF, 140, 32, 121, 97, BitOR($ES_AUTOVSCROLL, $WS_VSCROLL, $ES_MULTILINE))
GUICtrlSetLimit($myedit, 1500)
$Status = GUICtrlCreateLabel("", 0, 234, 392, 20, BitOR($SS_SUNKEN, $SS_CENTER))
$Btn_GET = GUICtrlCreateButton("Get", 150, 130, 90, 40, $BS_MULTILINE)

; will be append dont' forget 3rd parameter
GUICtrlSetData($myedit, "2nd line" & @CRLF & "3rd line" & @CRLF & "4th line" & @CRLF & _
      "5th line" & @CRLF & "6th line" & @CRLF & "7th line" & @CRLF & "8th line" & @CRLF & "9th line", 1)

GUISetState()

; Run the GUI until the dialog is closed
While 1
   $msg = GUIGetMsg()
   Select
      Case $msg = $GUI_EVENT_CLOSE
         ExitLoop
      Case $msg = $Btn_GET
         GUICtrlSetData($Status, "Line From Char: " & _GUICtrlEditLineFromChar ($myedit))
   EndSelect
WEnd